To open the Volume Mixer, either left click once, then click Mixer", or right click the speaker icon and select Open Volume Mixer directly.

Another method is to hit Windows to open a box, and type "sndvol" and hit return. This will also launch the mixer.

Once the mixer is showing you can scroll through the open sound producing applications, and adjust their volumes individiually. The relative volumes are typically remembered between executions, but some applications or games will have their own mind on the matter.

To mute an application entirely, click on the speaker icon under the volume slider.

How to mute with a keypress using AutoHotkey

Users of Windows automation software AutoHotkey will appreciate this handy script, which allows you to mute a single selected application with the press of a key. This is helpful when your are playing a game and also watching video, and want to mute the TV, for example, without affecting your game sound.

#NoEnv ;// Recommended for new scripts
#Persistent ;// Recommended for new scripts
SendMode Input  ;// Recommended for new scripts
SetTitleMatchMode 2

;// Set VolumeMute to only silence Media Center
$Volume_Mute::
	MuteMediaCenter()
	return
;// Control+VolumeMute is the system mute now
^Volume_Mute::Volume_Mute

MuteMediaCenter()
{	
	;// Open mixer
	Run sndvol 
	WinWait Volume Mixer
	;// Mute Standard Media Center Process
	appName = Windows Media Center
	MuteApp(appName)
	;// Mute Netflix Media Center Process
	appName = Media Center Extensibility Host
	MuteApp(appName)
	;// Mute Hulu App
	appName = Hulu Desktop
	MuteApp(appName)
	;// Close mixer
	WinClose Volume Mixer
}

;// Volume Mixer must exist
MuteApp(appName) 
{
	;// Find X position & width of textblock with text matching our appName
	ControlGetPos, refX, , refW, , % appName, Volume Mixer
	;// Find button with left side within the width of the textblock
	x = -1
	while ( x != "") 
	{
		;// A_Index is current loop iteration→used to find id
		tbIDX := (A_Index * 2) 
		ControlGetPos, x, , , , ToolbarWindow32%tbIDX%, Volume Mixer
		diff := x - refX
		if (diff > 0 && diff < refW)
		{
			;// msgbox diff: %diff% refX: %refX% tbIDX: %tbIDX% x: %x% A_Index: %A_Index%
			ControlClick, ToolbarWindow32%tbIDX%, Volume Mixer
			break
		}
	}
}

This script will mute only Windows Media Center when your press the Mute button on your keyboard. It works by finding and clicking the proper mute button in the Volume Mixer. Sometimes the very first time you use it, it takes a moment while the mixer panel launches, but afterward it will be nearly instanataneous.

The script can be easily adapted for use, and you can edit it to mute any application or set of applications, for any particular keystroke.